//------------------------------------------------------------------
#property copyright   "copyright© mladen"
#property link        "mladenfx@gmail.com"
//------------------------------------------------------------------
#property indicator_separate_window
#property indicator_buffers  4
#property indicator_plots    3
#property indicator_label1   "Trend"
#property indicator_type1    DRAW_FILLING
#property indicator_color1   clrLightGreen,clrOrange
#property indicator_label2   "Real"
#property indicator_type2    DRAW_LINE
#property indicator_color2   clrMediumSeaGreen
#property indicator_width2   2
#property indicator_label3   "Imaginary"
#property indicator_type3    DRAW_LINE
#property indicator_color3   clrOrangeRed
#property indicator_width3   2

//
//
//

input int  inpPeriod = 35; // Period

double valr[],vali[],fillu[],filld[],tcos[],tsin[];
struct sGlobalStruct
{
   double real,imag,cSx,sSx,cSy,sSy,cSxx,sSxx,cSxy,sSxy,cSyy,sSyy,X,cY,sY; 
   int    lim;
};
sGlobalStruct glo;

//------------------------------------------------------------------
//
//------------------------------------------------------------------

int OnInit()
{
   SetIndexBuffer(0,fillu,INDICATOR_DATA); 
   SetIndexBuffer(1,filld,INDICATOR_DATA); 
   SetIndexBuffer(2,valr ,INDICATOR_DATA); 
   SetIndexBuffer(3,vali ,INDICATOR_DATA); 
      
   //
   //
   //

   ArrayResize(tcos,inpPeriod); for (int i=0; i<inpPeriod; i++) tcos[i] =  cos(i*2*M_PI/(double)inpPeriod); 
   ArrayResize(tsin,inpPeriod); for (int i=0; i<inpPeriod; i++) tsin[i] = -sin(i*2*M_PI/(double)inpPeriod); 
   
   IndicatorSetString(INDICATOR_SHORTNAME,StringFormat("Correlation angle (%i)",inpPeriod));
return(INIT_SUCCEEDED);
}
void OnDeinit(const int reason) {  return; }

//------------------------------------------------------------------
//
//------------------------------------------------------------------

int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long& tick_volume[],
                const long& volume[],
                const int& spread[])
{
   glo.lim = prev_calculated-1; if (glo.lim<0) glo.lim = 0;

   //
   //
   //
   
   for (int i=glo.lim; i<rates_total; i++)
   {
      vali[i]  = filld[i] = 0;
      valr[i]  = fillu[i] = 0;
      glo.cSx  = glo.sSx  = 0; 
      glo.cSy  = glo.sSy  = 0; 
      glo.cSxx = glo.sSxx = 0; 
      glo.cSxy = glo.sSxy = 0; 
      glo.cSyy = glo.sSyy = 0; 
      for (int k=0; k<inpPeriod && i>=k; k++)
      {
	      glo.X    = close[i-k]; 
	      glo.cY   = tcos[k]; 
	      glo.sY   = tsin[k]; 
	      glo.cSx  = glo.cSx  + glo.X ; 
	      glo.cSy  = glo.cSy  + glo.cY; 
	      glo.cSxx = glo.cSxx + glo.X  *  glo.X; 
	      glo.cSxy = glo.cSxy + glo.X  * glo.cY; 
	      glo.cSyy = glo.cSyy + glo.cY * glo.cY; 
	      glo.sSx  = glo.sSx  + glo.X ; 
	      glo.sSy  = glo.sSy  + glo.sY; 
	      glo.sSxx = glo.sSxx + glo.X  *  glo.X; 
	      glo.sSxy = glo.sSxy + glo.X  * glo.sY; 
	      glo.sSyy = glo.sSyy + glo.sY * glo.sY; 
      }
      if ((inpPeriod*glo.cSxx-glo.cSx*glo.cSx > 0 ) && (inpPeriod*glo.cSyy-glo.cSy*glo.cSy > 0 )) valr[i] = fillu[i] = (inpPeriod*glo.cSxy-glo.cSx*glo.cSy)/sqrt((inpPeriod*glo.cSxx-glo.cSx*glo.cSx)*(inpPeriod*glo.cSyy-glo.cSy*glo.cSy)); 
      if ((inpPeriod*glo.sSxx-glo.sSx*glo.sSx > 0 ) && (inpPeriod*glo.sSyy-glo.sSy*glo.sSy > 0 )) vali[i] = filld[i] = (inpPeriod*glo.sSxy-glo.sSx*glo.sSy)/sqrt((inpPeriod*glo.sSxx-glo.sSx*glo.sSx)*(inpPeriod*glo.sSyy-glo.sSy*glo.sSy)); 
   }      
return(rates_total);
}